ps4nixos/base.nix

{ config, pkgs, lib, modulesPath, ... }: {
  fileSystems = {
    "/boot" = {
      device = "/dev/disk/by-label/nixos-boot";
      fsType = "vfat";
      options = [ "nofail" "noauto" ];
    };
    "/" = {
      device = "/dev/disk/by-label/nixos-root";
      fsType = "ext4";
    };
  };

  boot.loader.grub.enable = false;

  system.build.rootFileSystem = pkgs.callPackage (modulesPath + "/../lib/make-ext4-fs.nix") {
    storePaths = with pkgs; [
      config.system.build.toplevel
    ];
    volumeLabel = "nixos-root";
    populateImageCommands = ''
      cp ${config.system.build.toplevel}/init ./files/init
      touch ./files/firstboot
    '';
  };

  # from https://github.com/NixOS/nixpkgs/blob/e405f30513169feedb64b5c25e7b00242010af58/nixos/modules/installer/sd-card/sd-image.nix#L267
  boot.postBootCommands = let
      expandOnBoot = ''
        # Figure out device names for the boot device and root filesystem.
        rootPart=$(${pkgs.util-linux}/bin/findmnt -n -o SOURCE /)
        bootDevice=$(lsblk -npo PKNAME $rootPart)
        partNum=$(lsblk -npo MAJ:MIN $rootPart | ${pkgs.gawk}/bin/awk -F: '{print $2}')

        # Resize the root partition and the filesystem to fit the disk
        echo ",+," | sfdisk -N$partNum --no-reread $bootDevice
        ${pkgs.parted}/bin/partprobe
        ${pkgs.e2fsprogs}/bin/resize2fs $rootPart
      '';
      firstbootFile = "/firstboot";
    in ''
      # On the first boot do some maintenance tasks
      if [ -f ${firstbootFile} ]; then
        set -euo pipefail
        set -x

        ${expandOnBoot}

        # TODO what does all this do?

        # Register the contents of the initial Nix store
        # ${config.nix.package.out}/bin/nix-store --load-db < ${firstbootFile}

        # nixos-rebuild also requires a "system" profile and an /etc/NIXOS tag.
        # touch /etc/NIXOS
        # ${config.nix.package.out}/bin/nix-env -p /nix/var/nix/profiles/system --set /run/current-system

        # Prevents this from running on later boots.
        rm -f ${firstbootFile}
      fi
    '';

  # system.build.usbImage = pkgs.callPackage ({ stdenvNoCC }: stdenvNoCC.mkDerivation {
  #   name = "nixos-ps4-usbimage";

  #   nativeBuildInputs = with pkgs; [ mtools ];

  #   buildCommand = ''
  #     mkdir $out
  #     dd if=/dev/zero of=$out/nixos.img bs=1M count=2
  #     mformat -F -i $out/nixos.img ::
  #     mcopy -i $out/nixos.img ${config.system.build.system.kernel}/bzImage
  #   '';
  # }) {};

  boot.initrd.preFailCommands = ''
    export allowShell=1
  '';

  users.users.nixos = {
    isNormalUser = true;
    password = "nixos";
    extraGroups = [ "wheel" ];
  };

  users.defaultUserShell = pkgs.fish;
  programs.fish.enable = true;

  services.getty.autologinUser = "nixos";
}